So erstellen sie den E-Mail Link Button

Schritt 1 - FM20.DLL

Als erstes müssen sie die DLL "FM20.DLL" aus der Bibliothek "Forms 2.0 Library" auf ihrem System installieren.

Gehen sie wie folgt vor:

Öffnen sie das Menü "Extras" -> "Verweise"

Haken setzen bei "Microsoft Forms 2.0 Object Library"

Bestätigen und Fenster schliessen mit "OK"

Hinweis: Sollte die Option nicht vorhanden sein, müssen sie zuerst die DLL finden: "C:\Windows\system32\FM20.DLL" Ist diese nicht vorhanden müssen sie diese in das Verzeichnis kopieren.

Schritt 2 - MS Visual Basic Script

Folgenden Script im MS Visual Basic Editor erstellen:

Sub CopyItemIDs()
    Dim myOLApp As Application
    Dim myNameSpace As NameSpace
    Dim currentMessage As MailItem
    Dim ClipBoard As String
    Dim DataO As DataObject
   
    ' Makro Umgebung erstellen
    Set myOLApp = CreateObject("Outlook.Application")
    Set myNameSpace = myOLApp.GetNamespace("MAPI")
   
    ' Herausfinden ob das aktive Fenster mehrere oder nur eine Nachricht zeigt
    ' im eigenen Fenster
    On Error GoTo QuitIfError    ' Bei Fehler beendent
    Select Case myOLApp.ActiveWindow.Class
        ' Das aktive Fenster ist eine Liste von Nachrichten (Ordner); das bedeutet
        ' es könnten mehrere Nachrichten ausgewählt sein
        Case olExplorer
            ' Abalge erstellen
            For Each currentMessage In myOLApp.ActiveExplorer.Selection
                ClipBoard = GetMsgDetails(currentMessage, ClipBoard)
            Next
            
        ' Das aktive Fenster ist ein Nachrichten-Fenster, das bedeutety
        ' nur eine Nachricht ist ausgewählt (in diesem Fenster)
        Case olInspector
            ' Ablage erstellen
            ClipBoard = GetMsgDetails(myOLApp.ActiveInspector.CurrentItem, _
                                         ClipBoard)
        ' andere Fenster nicht möglich und werden ignoriert
    End Select
   
QuitIfError:        ' Bei Fehlermeldung geht es hier weiter
    Set myOLApp = Nothing
    Set myNameSpace = Nothing
    Set currentMessage = Nothing

    Set DataO = New DataObject
    DataO.Clear
    DataO.SetText ClipBoard
    DataO.PutInClipboard
   
    Set DataO = Nothing

End Sub

Function GetMsgDetails(Item As MailItem, Details As String) As String

    If Details <> "" Then
        Details = Details + vbCrLf
    End If
    'Details = Details + Item.Subject + vbCrLf
    Details = Details + "Outlook:" + Item.EntryID + vbCrLf

    GetMsgDetails = Details

End Function

Schritt 3 - Button erstellen und mit Makro verknüpfen

Jetzt nur noch einen neuen "Button" in Outlook erstellen und diesen das Makro zuweisen.

Fertig!